85955

Cчетчик обратного отсчета

Курсовая

Информатика, кибернетика и программирование

Ввод необходимо осуществлять с помощью стандартной шестнадцатикнопочной терминальной клавиатуры. Переход в режим установки времени необходимо осуществлять нажатием клавиши 0. Выход из режима установки времени должен происходить автоматически по окончании ввода значений всех регистров.

Русский

2015-04-01

247.5 KB

1 чел.

Московский государственный институт электроники и математики

(технический университет)

Кафедра электронно-вычислительной аппаратуры

Курсовая работа по дисциплине

«Микропроцессорные системы»

Тема “Cчетчик обратного отсчета”

Исполнитель:

студент группы С-85

Обухов М. Ю.

Проверил:

преподаватель каф. ЭВА

Гудков Ю.И.

Москва – 2007

Оглавление

[1] Оглавление

[2]
Техническое задание

[3]
Описание работы программы

[3.1] Логика построения программы

[3.2] Устройства ввода

[4]
Текст программы


Техническое задание

Разработать программу на языке Assembler, отсчитывающую время от заданного значения до 0. Значение может быть от 0001 до 9999.

2 режима работы:

1) режим установки значения

2) режим отсчета

Ввод необходимо осуществлять с помощью стандартной шестнадцатикнопочной терминальной клавиатуры. Переход в режим установки времени необходимо осуществлять нажатием клавиши 0. Выход из режима установки времени должен происходить автоматически по окончании ввода значений всех регистров.


Описание работы программы

Логика построения программы

Исходя из ТЗ сформируем следующую блок-схему работы основной программы:

Устройства ввода

Для ввода данных используется стандартная шестнадцатикнопочная клавиатура, подключаемая к параллельному порту (P1). Она имеет следующий вид:

Чтобы определить, нажата или нет какая-либо клавиша-ключ, сначала нужно выставить на линии регистра-защёлки P1, которые соединяет клавиша, разные логические значения. Затем необходимо считать из регистра значения этих линий: если оба бита стали равными «0», то значит, проверяемая клавиша была нажата.

Для сокращения процедуры опроса клавиатуры будем делать опрос по «строкам»:

1

1

1

1

1

1

1

0

0

1

1

1

‘7’

0

1

1

1

1

1

1

1

0

1

1

1

1

1

0

1

‘8’

0

1

1

1

1

1

1

1

0

1

1

1

1

1

1

0

‘9’

0

1

1

1

1

1

1

1

0

1

1

1

0

1

1

1

‘0’

1

0

1

1

1

1

1

1

1

0

1

1

1

1

0

1

Клавиша

Слово, выставленное на P1

Ожидаемое на P1 слово

7

6

5

4

3

2

1

0

7

6

5

4

3

2

1

0

‘1’

1

1

0

1

1

1

1

1

1

1

0

1

1

1

0

1

‘2’

1

1

0

1

1

1

1

1

1

1

0

1

1

1

1

0

‘3’

1

1

0

1

1

1

1

1

1

1

0

1

0

1

1

1

‘4’

1

1

1

0

1

1

1

1

1

1

1

0

1

1

0

1

‘5’

1

1

1

0

1

1

1

1

1

1

1

0

1

1

1

0

‘6’

1

1

1

0

Чтобы просто зафиксировать факт нажатия любой из цифровых клавиш, достаточно выставить в регистр P1 слово #00001111b и ожидать на P1 значение #0000x1xxb, где x{0;1}.

Особенностью данной клавиатуры, которую надо учитывать при программировании, является наличие переходного процесса (дребезга) с длительностью  в несколько раз большей, чем время машинного цикла ОМЭВМ МК8051:

 


Текст программы

ORG 8000h;

  jmp  lbMain

ORG 800Bh;

  jmp intTF0

 lbMain:

   ; конфигурируем таймер T0:

     anl TMOD, #0F0h; обнуляем младшую тетраду

     orl TMOD, #01h; младшую тетраду приводим к виду "0001"

     clr TR0; остановка таймера T0 (таймер - не считает)

     ; загружаем старший и младший байты регистра таймера T0 нулями:

       mov TH0, #0

       mov TL0, #0  

   ; настраиваем систему прерываний:

     mov IP, #0; все прерывания (пока) - с одинаковым низким уровнем приоритета

     mov IE, #10000010b; IEN0: выставили биты EA(7),ES(4),ET0(1)

     ;mov 0E8h, #00001011b; IEN1: выставили биты 0,1,3

     mov P1, #00001111b

     mov 0EBh,#0FFh;

;;;; ОПИСАНИЕ ПЕРЕМЕННЫХ: ;;;;

 ;регистр R0 - единицы

 ;регистр R1 - десятки

 ;регистр R2 - сотни

 ;регистр R3 - тысячи

 ;регистры R4, R5, R6 - для разных промежуточных значений

 ;регистр R7 - буфер для хранения значения нажатой клавиши [#0..#9] или

 ;             значения #FFh, если клавиша не нажата

 CR  equ 0Dh; "возврат каретки"

 LF  equ 0Ah; "перевод строки"

 ESC equ 1Bh; "конец сообщения"

 

 Buf_R0 equ 20h

 Buf_R1 equ 21h

 Buf_R2 equ 22h

 Buf_R3 equ 23h

 

;;;; ТЕЛО ПРОГРАММЫ: ;;;;

 ;задаём начальное время:

 mov R0, #0;

 mov R1, #2;

 mov R2, #1;

 mov R3, #0;

 mov Buf_R0, R0

 mov Buf_R1, R1

 mov Buf_R2, R2

 mov Buf_R3, R3

 mov DPTR, #msgShowTime_Mode

 call prShowMessage; вывод сообщения msgShowTime_Mode

 

 setb TR0

 mov R4, #13

 lbMainLoop:

     nop

     clr A

     add A, R0

     add A, R1

     add A, R2

     add A, R3

     jz lbFinal

   jmp lbMainLoop

   ;call prDelay;

   ;call prDisplay;

   ;call prIs_SetTime_Mode;

 intTF0:

   clr TF0

   djnz R4, lbTF0_End;

   ; реализация обратного отсчёта:

     dec R0

     cjne R0, #0FFh, lbTF0_Next1;

       mov R0, #9

       dec R1

       cjne R1, #0FFh, lbTF0_Next1;

         mov R1, #9

         dec R2

         cjne R2, #0FFh, lbTF0_Next1;

           mov R2, #9

           dec R3

           cjne R3, #0FFh, lbTF0_Next1;

   

   lbTF0_Next1: mov R4, #13

   lbTF0_End:   call prDisplay

 reti

 lbFinal:

   clr TR0

   mov DPTR, #msgFinal

   call prShowMessage

   ;call prIs_SetTime_Mode;

   jmp $

;;;; ОПИСАНИЕ ПРОЦЕДУР: ;;;;

;; процедура prDelay:

;    lb5: mov R5, #1;

;

;    lb3: djnz R6, lb3

;      djnz R4, lb3

;        djnz R5, lb3

;

;    ret

;

;  prDelay:

;    mov R6, #0

;    mov R4, #0

;    mov R5, #6

;    call lb3

;

;    mov R4, #244; (!!!)

;    call lb5

;

;    mov R4, #1

;    mov R6, #118; (!!!) Это следует менять для подстройки задержки!!!

;    call lb5

;

;  ret

;; процедура prSmartDelay:

;;   небольшая задержка, за время которой на клавиатуре успевает

;;   завершиться "переходный процесс"

 prSmartDelay:

   mov R6, #0

   mov R5, #0

   lbSmartDelay_Loop:

     djnz R5, $

     djnz R6, lbSmartDelay_Loop

   ret

;; процедура prDisplay:

;; [2 на вызов]+[2 на возврат]+[7]+[1]+[1432]=[1444]

   ;; переводим значения R0, R1, R2 в кодировку ACSII:

   lbDrawElement:

     add A, #30h

     call prWaitFor_TI

     mov SBUF, A

   ret

 prDisplay:

   call prWaitFor_TI

   mov SBUF, #CR; переводим курсор в начало строки:

   mov A, R3

   call lbDrawElement

   mov A, R2

   call lbDrawElement

   mov A, R1

   call lbDrawElement

   mov A, R0

   call lbDrawElement

   call prWaitFor_TI; для выравнивания подождём передачи последнего символа

   setb TI; [1] иначе - программа "зависнет"

 ret; [2]

;; процедура prWaitFor_TI:

;;   ожидание "готовности передачи" по последовательному порту

 prWaitFor_TI:

   jnb TI, $; зациклить, пока TI=0

   clr TI   ; устанавливаем "неготовность пердачи"

   ret

;; процедура prIs_SetTime_Mode:

;; [2 на вызов]+[2+1+2+2]=[9]

;;   проверяет, нажата ли клавиша входа в режим установки времени;

;;   такой клавишей явл. '0'

 prIs_SetTime_Mode:

   mov P1, #00BFh

   mov A, P1

   cjne A, #00BEh, lbNot_SetTime_Mode

     call prSetTime; переход в режим установки таймера

   lbNot_SetTime_Mode:

     cjne A, #00B7h, lbNotAnyMode

       mov R0, Buf_R0

       mov R1, Buf_R1

       mov R2, Buf_R2

       mov R3, Buf_R3

   lbNotAnyMode: ret

;; процедура prExam_NumKeys:

;;   опрос цифровых клавиш

   prExam_NumKeys:

     mov R7, #0FFh; допустим, что ничего не будет нажато

     ;опрос первого столбца клавиш:

     lbKey_1:

       mov P1, #00DFh

       mov A, P1

       cjne A, #00DDh, lbKey_2

         mov R7, #1

         ret

     lbKey_2:

       cjne A, #00DEh, lbKey_3

         mov R7, #2

         ret

     lbKey_3:

       cjne A, #00D7h, lbKey_4

         mov R7, #3

         ret

     ;опрос второго столбца клавиш:

     lbKey_4:

       mov P1, #00EFh

       mov A, P1

 

       cjne A, #00EDh, lbKey_5

         mov R7, #4

         ret

     lbKey_5:

       cjne A, #00EEh, lbKey_6

         mov R7, #5

         ret

     lbKey_6:

       cjne A, #00E7h, lbKey_7

         mov R7, #6

         ret

     ;опрос третьего столбца клавиш:

     lbKey_7:

       mov P1, #007Fh

       mov A, P1

       cjne A, #007Dh, lbKey_8

         mov R7, #7

         ret

     lbKey_8:

       cjne A, #007Eh, lbKey_9

         mov R7, #8

         ret

     lbKey_9:

       cjne A, #0077h, lbKey_0

         mov R7, #9

         ret

     ;опрос четвёртого столбца клавиш:

     lbKey_0:

       mov P1, #00BFh

       mov A, P1

       cjne A, #00BDh, lbEnd_Exam_NumKeys

         mov R7, #0

         lbEnd_Exam_NumKeys:  ret

;; процедура prWaitFor_NextKey_Pressed:

;;   ждёт СЛЕДУЮЩЕГО НАЖАТИЯ, чтобы долгое нажатие не "флудило"

   prWaitFor_NextKey_Pressed:

     lbPrevKey_Pressed: call prSmartDelay; чтоб избежать "дребезга" клавиатуры

                        call prExam_NumKeys;

                        cjne R7, #0FFh, lbPrevKey_Pressed;

                          call prSmartDelay; чтоб избежать "дребезга" клавиатуры

                          lbNo_NextKey_Pressed: call prExam_NumKeys

                          cjne R7, #0FFh, lbNextKey_Pressed

                            jmp lbNo_NextKey_Pressed

                            

                            lbNextKey_Pressed: ret

;; процедура prSetTime:

;;   режим установки таймера:

   prSetTime:

     mov DPTR, #msgSetTime_Mode

     call prShowMessage; вывод сообщения msgSetTime_Mode

     call prDisplay

     ;регистр R3:

       call prWaitFor_NextKey_Pressed;

       mov R3, 07

       call prDisplay

     ;регистр R2:

       call prWaitFor_NextKey_Pressed

       mov R2, 07

       call prDisplay

     ;регистр R1:

       call prWaitFor_NextKey_Pressed

       mov R1, 07

       call prDisplay

     ;регистр R0:

       call prWaitFor_NextKey_Pressed

       mov R0, 07

       call prDisplay

     

     mov Buf_R0, R0

     mov Buf_R1, R1

     mov Buf_R2, R2

     mov Buf_R3, R3

     

     mov DPTR, #msgShowTime_Mode

     call prShowMessage; вывод сообщения msgShowTime_Mode

     

   ret

;; процедуры prIs_R0_more_59, prIs_R1_more_59, prIs_R2_more_23:

;;   проверяют соответствующие регистры на корректность значений в них;

;;   большие значения уменьшаются до ближайших верных

 prCorrect_R0:

   cjne R0, #59, lbR0_not_59

     ret

   lbR0_not_59: jnc lbR0_more_59

                ret

   lbR0_more_59: mov R0, #59

                 ret

 prCorrect_R1:

   cjne R1, #59, lbR1_not_59

     ret

   lbR1_not_59: jnc lbR1_more_59

                ret

   lbR1_more_59: mov R1, #59

                 ret

 prCorrect_R2:

   cjne R2, #23, lbR2_not_23

     ret

   lbR2_not_23: jnc lbR2_more_23

                ret

   lbR2_more_23: mov R2, #23

                 ret

;; процедура prShowMessage:

;;   выводит на экран текстовое сообщение; символ ESC - признак конца сообщения

 prShowMessage:

   clr A

   movc A, @A + DPTR

   lbNextSymbol: call prWaitFor_TI

                 mov SBUF, A

                 inc DPTR

                 clr A

                 movc A, @A + DPTR

                 cjne A, #ESC, lbNextSymbol

                   ret

;;;; ОПИСАНИЕ ТЕКСТОВЫХ СООБЩЕНИЙ: ;;;;

 msgSetTime_Mode:  db LF,CR, '[Regim ustanovki taymera:]', CR, LF, ESC

 msgShowTime_Mode: db LF,CR, 'OBRATNYI OTSCHET...', CR, LF, ESC

 msgFinal: db CR, '!!!OBRATNYI OTSCHET ZAKONCHEN!!!:', CR, LF, ESC

END;;;; КОНЕЦ ПРОГРАММЫ


 

А также другие работы, которые могут Вас заинтересовать

48351. РОЛЬ И МЕСТО СТРОИТЕЛЬСТВА В ЭКОНОМИКЕ СТРАНЫ 1.85 MB
  Неустойчивость соотношения строительномонтажных работ по их сложности и видам в течение месяца что затрудняет расчет численного и профессиональноквалификационного состава рабочих. Роль климата и местных условий в строительных работах. К наиболее значимым нарушениям природной среды относятся: нарушение верхнего покрова почвы при выполнении земляных работ и потеря растительного слоя; вырубка лесов и зеленых насаждений и т. Структура сметной стоимости строительства и строительномонтажных работ.
48352. Технология конструкционных материалов. Материаловедение, конспект лекций 1.25 MB
  Поверхностное упрочнение стали Поверхностная закалка стали Углеродистые стали Легированные стали и сплавы. Проектирование рациональных, конкурентоспособных изделий, организация их производства невозможны без должного технологического обеспечения и достаточного уровня знаний в области материаловедения и технологии. Последние являются важнейшим показателем образованности инженера в области техники.
48353. Русский язык и культура речи 283 KB
  Культура речи как учебная дисциплина Культура речи изучается в высших учебных заведениях как составная часть цикла гуманитарных дисциплин предназначенного для студентов всех специальностей. Предметом культуры речи как учебной дисциплины являются нормы литературного языка виды общения его принципы и правила этические нормы общения функциональные стили речи основы искусства речи а также трудности применения речевых норм и проблемы современного состояния речевой культуры общества.; повышение культуры разговорной речи обучение речевым...
48354. Социология 526.5 KB
  Социология logos учение наука об обществе о законах строения функционирования изменения и развития как общества в целом так и отдельных его систем и подсистем вплоть до малых групп. Так история изучает прошлое человеческого общества политология политические процессы и явления экономическая наука экономические процессы во всей их полноте и разнообразии демография количественные показатели рождаемости и смертности т. Метод социологии это специфическое проявление социально-философского метода во всестороннем изучении общества как...
48355. Исследование операций в бухгалтерском учете 272.5 KB
  Проблема выбора решения в условиях неопределенности. Решения могут быть удачными и неудачными разумными и неразумными. Оптимальными называются решения по тем или другим признакам предпочтительные перед другими. Заметим что само принятие решения выходит за рамки исследования операций и относится к компетенции ответственного лица чаще группы лиц которым предоставлено право окончательного выбора и на которых возложена ответственность за этот выбор.
48356. Лекции по акушерству 753 KB
  Гипоксия плода и новорожденного 6 Лекция №6. Гипоксия плода продолжение лекции №5 13 Лекция №9. Родовые травмы плода и новорожденного 61 VII семестр. Морфогенез плаценты зависит от развития маточноплацентарного кровообращения а не от кровообращения у плода.
48357. Дошкольная педагогика 1.61 MB
  В своих научных труда Всеобщий совет Великая дидактика Материнская школа он отразил цели и задачи формы и методы воспитания и обучения детей. Предмет дошкольной педагогики процесс воспитания его цель задачи содержание формы методы средства воспитания детей дошкольного возраста. способствовать воспитанию и обучению детей от рождения до школы теоретический и методический аспект в соответствии с требованиями современного общества; 2. разработать новые концепции и технологии воспитания и обучения детей дошкольного возраста.
48358. Концепции современного естествознания 764 KB
  Специфические черты науки: Наука универсальна она сообщает знания истинные для всего универсума при тех условиях при которых они добыты человеком. сложилась следующая система наук: математические и естественные науки естествознание система наук о природе; социальные науки человекознание система наук о человеке и обществе; технические науки техникознание система наук наиболее тесно связанных с реализацией теоретического знания. Выделяются науки фундаментальные и прикладные. Фундаментальные науки...
48359. ОСНОВЫ ОБЩЕЙ И СОЦИАЛЬНОЙ ПСИХОЛОГИИ 1.26 MB
  Структура психики человека. psyche психика logos учение наука о психическом отражении действительности в процессе деятельности человека. В системе человек право в первую очередь реализуются личностные качества человека как общественного существа включенного в социальные отношения как носителя сознания и в частности правосознания. Правовое регулирование деятельности человека в обществе и государстве осуществляется в сложнейших условиях характеризуется разнообразием моральных и правовых отношений возникающих в сфере...